mirror of
https://github.com/qbittorrent/qBittorrent.git
synced 2025-12-20 07:27:22 -06:00
1a21f45c75
Newer compilers have C++14 mode as default and package maintainers tend to not specifying a C++ version when building a package, this causes compatibility issues when (for example) qbt is compiled in C++11 and dependency lib is in C++14. See issue #9485. What this commit does: 1. Checks if compiler supports at least C++11 2. Checks if compiler is set in at least C++11 mode
77 lines
1.5 KiB
Prolog
77 lines
1.5 KiB
Prolog
# Global
|
|
TEMPLATE = app
|
|
CONFIG += qt thread silent
|
|
|
|
# Platform specific configuration
|
|
win32: include(../winconf.pri)
|
|
macx: include(../macxconf.pri)
|
|
unix:!macx: include(../unixconf.pri)
|
|
|
|
QT += network xml
|
|
|
|
nogui {
|
|
TARGET = qbittorrent-nox
|
|
QT -= gui
|
|
DEFINES += DISABLE_GUI
|
|
} else {
|
|
TARGET = qbittorrent
|
|
QT += xml svg widgets
|
|
|
|
CONFIG(static) {
|
|
DEFINES += QBT_STATIC_QT
|
|
QTPLUGIN += qico
|
|
}
|
|
win32 {
|
|
QT += winextras
|
|
}
|
|
macx {
|
|
QT += macextras
|
|
LIBS += -lobjc
|
|
}
|
|
}
|
|
|
|
nowebui {
|
|
DEFINES += DISABLE_WEBUI
|
|
}
|
|
|
|
stacktrace {
|
|
DEFINES += STACKTRACE
|
|
win32 {
|
|
DEFINES += STACKTRACE_WIN_PROJECT_PATH=$$PWD
|
|
DEFINES += STACKTRACE_WIN_MAKEFILE_PATH=$$OUT_PWD
|
|
}
|
|
}
|
|
|
|
CONFIG(debug, debug|release): message(Project is built in DEBUG mode.)
|
|
CONFIG(release, debug|release): message(Project is built in RELEASE mode.)
|
|
|
|
# Disable debug output in release mode
|
|
CONFIG(release, debug|release) {
|
|
message(Disabling debug output.)
|
|
DEFINES += QT_NO_DEBUG_OUTPUT
|
|
}
|
|
|
|
# VERSION DEFINES
|
|
include(../version.pri)
|
|
|
|
DEFINES += QT_NO_CAST_TO_ASCII
|
|
# Efficient construction for QString & QByteArray (Qt >= 4.8)
|
|
DEFINES += QT_USE_QSTRINGBUILDER
|
|
DEFINES += QT_STRICT_ITERATORS
|
|
|
|
INCLUDEPATH += $$PWD
|
|
|
|
include(app/app.pri)
|
|
include(base/base.pri)
|
|
!nogui: include(gui/gui.pri)
|
|
!nowebui: include(webui/webui.pri)
|
|
|
|
# Resource files
|
|
QMAKE_RESOURCE_FLAGS += -compress 9 -threshold 5
|
|
RESOURCES += \
|
|
icons/icons.qrc \
|
|
lang/lang.qrc \
|
|
searchengine/searchengine.qrc
|
|
|
|
DESTDIR = .
|