Updated vim plugins

sources_non_forked/vim-airline/autoload/airline/extensions/tabline/autoshow.vim

@@ -0,0 +1,51 @@
+" MIT License. Copyright (c) 2013-2015 Bailey Ling.
+" vim: et ts=2 sts=2 sw=2
+
+let s:show_buffers = get(g:, 'airline#extensions#tabline#show_buffers', 1)
+let s:buf_min_count = get(g:, 'airline#extensions#tabline#buffer_min_count', 0)
+let s:tab_min_count = get(g:, 'airline#extensions#tabline#tab_min_count', 0)
+
+function! airline#extensions#tabline#autoshow#off()
+  if exists('s:original_tabline')
+    let &tabline = s:original_tabline
+    let &showtabline = s:original_showtabline
+  endif
+
+  augroup airline_tabline_autoshow
+    autocmd!
+  augroup END
+endfunction
+
+function! airline#extensions#tabline#autoshow#on()
+  let [ s:original_tabline, s:original_showtabline ] = [ &tabline, &showtabline ]
+
+  augroup airline_tabline_autoshow
+    autocmd!
+    if s:buf_min_count <= 0 && s:tab_min_count <= 1
+      set showtabline=2
+    else
+      if s:show_buffers == 1
+        autocmd BufEnter  * call <sid>show_tabline(s:buf_min_count, len(airline#extensions#tabline#buflist#list()))
+        autocmd BufUnload * call <sid>show_tabline(s:buf_min_count, len(airline#extensions#tabline#buflist#list()) - 1)
+      else
+        autocmd TabEnter  * call <sid>show_tabline(s:tab_min_count, tabpagenr('$'))
+      endif
+    endif
+
+    " Invalidate cache.  This has to come after the BufUnload for
+    " s:show_buffers, to invalidate the cache for BufEnter.
+    autocmd BufAdd,BufUnload * call airline#extensions#tabline#buflist#invalidate()
+  augroup END
+endfunction
+
+function! s:show_tabline(min_count, total_count)
+  if a:total_count >= a:min_count
+    if &showtabline != 2
+      set showtabline=2
+    endif
+  else
+    if &showtabline != 0
+      set showtabline=0
+    endif
+  endif
+endfunction

sources_non_forked/vim-airline/autoload/airline/extensions/tabline/buffers.vim

@@ -0,0 +1,185 @@
+" MIT License. Copyright (c) 2013-2015 Bailey Ling.
+" vim: et ts=2 sts=2 sw=2
+
+scriptencoding utf-8
+
+let s:buffer_idx_mode = get(g:, 'airline#extensions#tabline#buffer_idx_mode', 0)
+let s:show_tab_type = get(g:, 'airline#extensions#tabline#show_tab_type', 1)
+let s:spc = g:airline_symbols.space
+
+let s:current_bufnr = -1
+let s:current_modified = 0
+let s:current_tabline = ''
+let s:current_visible_buffers = []
+
+let s:number_map = &encoding == 'utf-8'
+      \ ? {
+      \ '0': '⁰',
+      \ '1': '¹',
+      \ '2': '²',
+      \ '3': '³',
+      \ '4': '⁴',
+      \ '5': '⁵',
+      \ '6': '⁶',
+      \ '7': '⁷',
+      \ '8': '⁸',
+      \ '9': '⁹'
+      \ }
+      \ : {}
+
+function! airline#extensions#tabline#buffers#off()
+  augroup airline_tabline_buffers
+    autocmd!
+  augroup END
+endfunction
+
+function! airline#extensions#tabline#buffers#on()
+  augroup airline_tabline_buffers
+    autocmd!
+    autocmd BufDelete * call airline#extensions#tabline#buffers#invalidate()
+  augroup END
+endfunction
+
+function! airline#extensions#tabline#buffers#invalidate()
+  let s:current_bufnr = -1
+endfunction
+
+function! airline#extensions#tabline#buffers#get()
+  let cur = bufnr('%')
+  if cur == s:current_bufnr
+    if !g:airline_detect_modified || getbufvar(cur, '&modified') == s:current_modified
+      return s:current_tabline
+    endif
+  endif
+
+  let l:index = 1
+  let b = airline#extensions#tabline#new_builder()
+  let tab_bufs = tabpagebuflist(tabpagenr())
+  for nr in s:get_visible_buffers()
+    if nr < 0
+      call b.add_raw('%#airline_tabhid#...')
+      continue
+    endif
+
+    if cur == nr
+      if g:airline_detect_modified && getbufvar(nr, '&modified')
+        let group = 'airline_tabmod'
+      else
+        let group = 'airline_tabsel'
+      endif
+      let s:current_modified = (group == 'airline_tabmod') ? 1 : 0
+    else
+      if g:airline_detect_modified && getbufvar(nr, '&modified')
+        let group = 'airline_tabmod_unsel'
+      elseif index(tab_bufs, nr) > -1
+        let group = 'airline_tab'
+      else
+        let group = 'airline_tabhid'
+      endif
+    endif
+
+    if s:buffer_idx_mode
+      if len(s:number_map) > 0
+        call b.add_section(group, s:spc . get(s:number_map, l:index, '') . '%(%{airline#extensions#tabline#get_buffer_name('.nr.')}%)' . s:spc)
+      else
+        call b.add_section(group, '['.l:index.s:spc.'%(%{airline#extensions#tabline#get_buffer_name('.nr.')}%)'.']')
+      endif
+      let l:index = l:index + 1
+    else
+      call b.add_section(group, s:spc.'%(%{airline#extensions#tabline#get_buffer_name('.nr.')}%)'.s:spc)
+    endif
+  endfor
+
+  call b.add_section('airline_tabfill', '')
+  call b.split()
+  call b.add_section('airline_tabfill', '')
+  if s:show_tab_type
+    call b.add_section('airline_tabtype', ' buffers ')
+  endif
+
+  let s:current_bufnr = cur
+  let s:current_tabline = b.build()
+  return s:current_tabline
+endfunction
+
+function! s:get_visible_buffers()
+  let buffers = airline#extensions#tabline#buflist#list()
+  let cur = bufnr('%')
+
+  let total_width = 0
+  let max_width = 0
+
+  for nr in buffers
+    let width = len(airline#extensions#tabline#get_buffer_name(nr)) + 4
+    let total_width += width
+    let max_width = max([max_width, width])
+  endfor
+
+  " only show current and surrounding buffers if there are too many buffers
+  let position  = index(buffers, cur)
+  let vimwidth = &columns
+  if total_width > vimwidth && position > -1
+    let buf_count = len(buffers)
+
+    " determine how many buffers to show based on the longest buffer width,
+    " use one on the right side and put the rest on the left
+    let buf_max   = vimwidth / max_width
+    let buf_right = 1
+    let buf_left  = max([0, buf_max - buf_right])
+
+    let start = max([0, position - buf_left])
+    let end   = min([buf_count, position + buf_right])
+
+    " fill up available space on the right
+    if position < buf_left
+      let end += (buf_left - position)
+    endif
+
+    " fill up available space on the left
+    if end > buf_count - 1 - buf_right
+      let start -= max([0, buf_right - (buf_count - 1 - position)])
+    endif
+
+    let buffers = eval('buffers[' . start . ':' . end . ']')
+
+    if start > 0
+      call insert(buffers, -1, 0)
+    endif
+
+    if end < buf_count - 1
+      call add(buffers, -1)
+    endif
+  endif
+
+  let s:current_visible_buffers = buffers
+  return buffers
+endfunction
+
+function! s:select_tab(buf_index)
+  " no-op when called in the NERDTree buffer
+  if exists('t:NERDTreeBufName') && bufname('%') == t:NERDTreeBufName
+    return
+  endif
+
+  let idx = a:buf_index
+  if s:current_visible_buffers[0] == -1
+    let idx = idx + 1
+  endif
+
+  let buf = get(s:current_visible_buffers, idx, 0)
+  if buf != 0
+    exec 'b!' . buf
+  endif
+endfunction
+
+if s:buffer_idx_mode
+  noremap <unique> <Plug>AirlineSelectTab1 :call <SID>select_tab(0)<CR>
+  noremap <unique> <Plug>AirlineSelectTab2 :call <SID>select_tab(1)<CR>
+  noremap <unique> <Plug>AirlineSelectTab3 :call <SID>select_tab(2)<CR>
+  noremap <unique> <Plug>AirlineSelectTab4 :call <SID>select_tab(3)<CR>
+  noremap <unique> <Plug>AirlineSelectTab5 :call <SID>select_tab(4)<CR>
+  noremap <unique> <Plug>AirlineSelectTab6 :call <SID>select_tab(5)<CR>
+  noremap <unique> <Plug>AirlineSelectTab7 :call <SID>select_tab(6)<CR>
+  noremap <unique> <Plug>AirlineSelectTab8 :call <SID>select_tab(7)<CR>
+  noremap <unique> <Plug>AirlineSelectTab9 :call <SID>select_tab(8)<CR>
+endif

sources_non_forked/vim-airline/autoload/airline/extensions/tabline/buflist.vim

@@ -0,0 +1,38 @@
+" MIT License. Copyright (c) 2013-2015 Bailey Ling.
+" vim: et ts=2 sts=2 sw=2
+
+let s:excludes = get(g:, 'airline#extensions#tabline#excludes', [])
+
+function! airline#extensions#tabline#buflist#invalidate()
+  unlet! s:current_buffer_list
+endfunction
+
+function! airline#extensions#tabline#buflist#list()
+  if exists('s:current_buffer_list')
+    return s:current_buffer_list
+  endif
+
+  let buffers = []
+  let cur = bufnr('%')
+  for nr in range(1, bufnr('$'))
+    if buflisted(nr) && bufexists(nr)
+      let toadd = 1
+      for ex in s:excludes
+        if match(bufname(nr), ex) >= 0
+          let toadd = 0
+          break
+        endif
+      endfor
+      if getbufvar(nr, 'current_syntax') == 'qf'
+        let toadd = 0
+      endif
+      if toadd
+        call add(buffers, nr)
+      endif
+    endif
+  endfor
+
+  let s:current_buffer_list = buffers
+  return buffers
+endfunction
+

sources_non_forked/vim-airline/autoload/airline/extensions/tabline/formatters/default.vim

@@ -1,4 +1,4 @@
-" MIT License. Copyright (c) 2013-2014 Bailey Ling.
+" MIT License. Copyright (c) 2013-2015 Bailey Ling.
 " vim: et ts=2 sts=2 sw=2
 
 let s:fmod = get(g:, 'airline#extensions#tabline#fnamemod', ':~:.')
@@ -7,7 +7,7 @@ let s:buf_nr_format = get(g:, 'airline#extensions#tabline#buffer_nr_format', '%s
 let s:buf_nr_show = get(g:, 'airline#extensions#tabline#buffer_nr_show', 0)
 let s:buf_modified_symbol = g:airline_symbols.modified
 
-function! airline#extensions#tabline#default#format(bufnr, buffers)
+function! airline#extensions#tabline#formatters#default#format(bufnr, buffers)
   let _ = ''
 
   let name = bufname(a:bufnr)
@@ -21,10 +21,10 @@ function! airline#extensions#tabline#default#format(bufnr, buffers)
     endif
   endif
 
-  return airline#extensions#tabline#default#wrap_name(a:bufnr, _)
+  return airline#extensions#tabline#formatters#default#wrap_name(a:bufnr, _)
 endfunction
 
-function! airline#extensions#tabline#default#wrap_name(bufnr, buffer_name)
+function! airline#extensions#tabline#formatters#default#wrap_name(bufnr, buffer_name)
   let _ = s:buf_nr_show ? printf(s:buf_nr_format, a:bufnr) : ''
   let _ .= substitute(a:buffer_name, '\\', '/', 'g')
 

sources_non_forked/vim-airline/autoload/airline/extensions/tabline/formatters/unique_tail.vim

@@ -1,7 +1,7 @@
-" MIT License. Copyright (c) 2013-2014 Bailey Ling.
+" MIT License. Copyright (c) 2013-2015 Bailey Ling.
 " vim: et ts=2 sts=2 sw=2
 
-function! airline#extensions#tabline#unique_tail#format(bufnr, buffers)
+function! airline#extensions#tabline#formatters#unique_tail#format(bufnr, buffers)
   let duplicates = {}
   let tails = {}
   let map = {}
@@ -15,12 +15,12 @@ function! airline#extensions#tabline#unique_tail#format(bufnr, buffers)
         let duplicates[nr] = nr
       endif
       let tails[tail] = 1
-      let map[nr] = airline#extensions#tabline#default#wrap_name(nr, tail)
+      let map[nr] = airline#extensions#tabline#formatters#default#wrap_name(nr, tail)
     endif
   endfor
 
   for nr in values(duplicates)
-    let map[nr] = airline#extensions#tabline#default#wrap_name(nr, fnamemodify(bufname(nr), ':p:.'))
+    let map[nr] = airline#extensions#tabline#formatters#default#wrap_name(nr, fnamemodify(bufname(nr), ':p:.'))
   endfor
 
   return map[a:bufnr]

sources_non_forked/vim-airline/autoload/airline/extensions/tabline/formatters/unique_tail_improved.vim

@@ -1,13 +1,13 @@
-" MIT License. Copyright (c) 2013-2014 Bailey Ling.
+" MIT License. Copyright (c) 2013-2015 Bailey Ling.
 " vim: et ts=2 sts=2 sw=2
 
 scriptencoding utf-8
 
 let s:skip_symbol = '…'
 
-function! airline#extensions#tabline#unique_tail_improved#format(bufnr, buffers)
+function! airline#extensions#tabline#formatters#unique_tail_improved#format(bufnr, buffers)
   if len(a:buffers) <= 1 " don't need to compare bufnames if has less than one buffer opened
-    return airline#extensions#tabline#default#format(a:bufnr, a:buffers)
+    return airline#extensions#tabline#formatters#default#format(a:bufnr, a:buffers)
   endif
 
   let curbuf_tail = fnamemodify(bufname(a:bufnr), ':t')
@@ -84,8 +84,8 @@ function! airline#extensions#tabline#unique_tail_improved#format(bufnr, buffers)
       call insert(buf_name, s:skip_symbol)
     endif
 
-    return airline#extensions#tabline#default#wrap_name(a:bufnr, join(buf_name, '/'))
+    return airline#extensions#tabline#formatters#default#wrap_name(a:bufnr, join(buf_name, '/'))
   else
-    return airline#extensions#tabline#default#format(a:bufnr, a:buffers)
+    return airline#extensions#tabline#formatters#default#format(a:bufnr, a:buffers)
   endif
 endfunction

sources_non_forked/vim-airline/autoload/airline/extensions/tabline/tabs.vim

@@ -0,0 +1,80 @@
+" MIT License. Copyright (c) 2013-2015 Bailey Ling.
+" vim: et ts=2 sts=2 sw=2
+
+let s:show_tab_nr = get(g:, 'airline#extensions#tabline#show_tab_nr', 1)
+let s:tab_nr_type = get(g:, 'airline#extensions#tabline#tab_nr_type', 0)
+let s:show_close_button = get(g:, 'airline#extensions#tabline#show_close_button', 1)
+let s:show_tab_type = get(g:, 'airline#extensions#tabline#show_tab_type', 1)
+let s:close_symbol = get(g:, 'airline#extensions#tabline#close_symbol', 'X')
+
+let s:current_bufnr = -1
+let s:current_tabnr = -1
+let s:current_modified = 0
+
+function! airline#extensions#tabline#tabs#off()
+  augroup airline_tabline_tabs
+    autocmd!
+  augroup END
+endfunction
+
+function! airline#extensions#tabline#tabs#on()
+  augroup airline_tabline_tabs
+    autocmd!
+    autocmd BufDelete * call airline#extensions#tabline#tabs#invalidate()
+  augroup END
+endfunction
+
+function! airline#extensions#tabline#tabs#invalidate()
+  let s:current_bufnr = -1
+endfunction
+
+function! airline#extensions#tabline#tabs#get()
+  let curbuf = bufnr('%')
+  let curtab = tabpagenr()
+  if curbuf == s:current_bufnr && curtab == s:current_tabnr
+    if !g:airline_detect_modified || getbufvar(curbuf, '&modified') == s:current_modified
+      return s:current_tabline
+    endif
+  endif
+
+  let b = airline#extensions#tabline#new_builder()
+  for i in range(1, tabpagenr('$'))
+    if i == curtab
+      let group = 'airline_tabsel'
+      if g:airline_detect_modified
+        for bi in tabpagebuflist(i)
+          if getbufvar(bi, '&modified')
+            let group = 'airline_tabmod'
+          endif
+        endfor
+      endif
+      let s:current_modified = (group == 'airline_tabmod') ? 1 : 0
+    else
+      let group = 'airline_tab'
+    endif
+    let val = '%('
+    if s:show_tab_nr
+      if s:tab_nr_type == 0
+        let val .= ' %{len(tabpagebuflist('.i.'))}'
+      else
+        let val .= (g:airline_symbols.space).i
+      endif
+    endif
+    call b.add_section(group, val.'%'.i.'T %{airline#extensions#tabline#title('.i.')} %)')
+  endfor
+
+  call b.add_raw('%T')
+  call b.add_section('airline_tabfill', '')
+  call b.split()
+  if s:show_close_button
+    call b.add_section('airline_tab', ' %999X'.s:close_symbol.' ')
+  endif
+  if s:show_tab_type
+    call b.add_section('airline_tabtype', ' tabs ')
+  endif
+
+  let s:current_bufnr = curbuf
+  let s:current_tabnr = curtab
+  let s:current_tabline = b.build()
+  return s:current_tabline
+endfunction